blob: 57ac793f1b1ecbb026a614080c5cbf6cc66c6ea0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Yauhen Kirylau <actionless DOT loveless PLUS aur AT gmail MF com>
# Maintainer: Padraic Fanning <fanninpm AT miamioh DOT edu>
_pkgname=python-gaphas
pkgname="${_pkgname}-git"
pkgver=3.6.0.r9.gc89cf2c
pkgrel=1
pkgdesc="Diagramming widget library for Python"
arch=('x86_64' 'i686')
url="https://github.com/gaphor/gaphas"
license=('Apache')
source=(
"${_pkgname}::git+${url}.git#branch=main"
)
md5sums=('SKIP')
depends=(
'gtk3'
'python-gobject'
'python-cairo'
'python-importlib-metadata'
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-poetry-core'
)
optdepends=(
)
checkdepends=(
'python-pytest'
'xorg-server-xvfb'
)
provides=(
"${_pkgname}"
)
conflicts=(
"${_pkgname}"
)
build() {
cd "${srcdir}/${_pkgname}"
# Note: set `GIT_CEILING_DIRECTORIES` to prevent poetry
# from incorrectly using a parent git checkout info.
# https://github.com/pypa/build/issues/384#issuecomment-947675975
GIT_CEILING_DIRECTORIES="${PWD}/.." python -m build --wheel --no-isolation
}
check() {
cd "${srcdir}/${_pkgname}"
xvfb-run --auto-servernum pytest
}
pkgver() {
cd "${srcdir}/${_pkgname}"
git describe --tags --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
package() {
cd "${srcdir}/${_pkgname}"
python -m installer --destdir="$pkgdir" dist/*.whl
}
# vim: ft=PKGBUILD
|