PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: peippo <christoph.fink@gmail.com>

pkgname=python-geohexgrid
_name=${pkgname#python-}
pkgdesc="A Python library for making geographic flat-top hexagon grids"
url="https://github.com/mrcagney/geohexgrid"

pkgver=2.1.1
pkgrel=1

arch=("any")
license=("MIT")

depends=(
    "python"
    "python-geopandas"
    "python-rtree"
)
makedepends=(
    "python-build"
    "python-hatchling"
    "python-installer"
    "python-setuptools"
    "python-uv"
    "python-wheel"
)
checkdepends=(
    "python-numpy"
    "python-pytest"
    "python-shapely"
)

source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
b2sums=("330956d93e528fc933cd17680b48f3655112d102aff3bc2fed81f32f4180c326f0caa9396125f032734580a78e70643eedf5be24d7fe642bfe05a2f7fd1886f4")

build() {
    cd "${srcdir}"/${_name}-${pkgver}
    python -m build --wheel --no-isolation
}

check() {
    cd "${srcdir}"/${_name}-${pkgver}
    python -m pytest
}

package() {
    cd "${srcdir}/${_name}-${pkgver}"
    python -m installer --destdir="$pkgdir" dist/*.whl
}