PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: archlinux.info:tdy

pkgbase=python-git-remote-dropbox-git
pkgname=(python-git-remote-dropbox-git python2-git-remote-dropbox-git)
pkgver=r29.27cb825
pkgrel=1
pkgdesc="Use a Dropbox (shared) folder as a true Git remote"
arch=(any)
url=https://github.com/anishathalye/git-remote-dropbox
license=(MIT)
makedepends=(python-setuptools python2-setuptools git)
source=(git+https://github.com/anishathalye/git-remote-dropbox.git)
sha256sums=(SKIP)

pkgver() {
  cd git-remote-dropbox
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cp -a git-remote-dropbox{,-py2}
}

build() {
  cd git-remote-dropbox
  python setup.py build

  cd ../git-remote-dropbox-py2
  python2 setup.py build
}

package_python-git-remote-dropbox-git() {
  depends=(python-dropbox git dropbox)
  provides=(python-git-remote-dropbox)
  conflicts=(python-git-remote-dropbox)

  cd git-remote-dropbox
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_python2-git-remote-dropbox-git() {
  depends=(python2-dropbox git dropbox)
  provides=(python2-git-remote-dropbox)
  conflicts=(python2-git-remote-dropbox)

  cd git-remote-dropbox-py2
  python2 setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}