PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Kaizhao Zhang <zhangkaizhao@gmail.com>

pkgname=python-google-cloud-bigquery
_pkgname="${pkgname#python-}"
_pkg=python-bigquery
pkgver=3.4.1
pkgrel=1
pkgdesc="Google BigQuery API client library"
arch=('any')
url="https://github.com/googleapis/python-bigquery"
license=('Apache')
depends=(
	'python-dateutil'
	'python-google-api-core'
	'python-google-cloud-bigquery-storage'
	'python-google-cloud-core'
	'python-google-resumable-media'
	'python-grpcio'
	'python-packaging'
	'python-protobuf'
	'python-pyarrow'
	'python-requests')
makedepends=(
	'ipython'
	'python-build'
	'python-installer'
	'python-recommonmark'
	'python-setuptools'
	'python-sphinx'
	'python-wheel')
optdepends=(
	'ipython'
	'python-fastparquet: fastparquet support'
	'python-llvmlite: fastparquet support'
	'python-pandas: pandas support'
	'python-snappy: fastparquet support'
	'python-tqdm: tqdm support')
changelog=CHANGELOG.md
# source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
source=("$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/g/$_pkgname/$_pkgname-$pkgver.tar.gz")
sha256sums=('884689714d98a2364dde9c7c367e8228c7116108bbad7a6365dfde391638985b')

build() {
	cd "$_pkgname-$pkgver"
	python -m build --wheel --no-isolation
	# PYTHONPATH="$PWD" sphinx-build -b man docs/ _build
}

package() {
	cd "$_pkgname-$pkgver"
	python -m installer --destdir="$pkgdir/" dist/*.whl
	install -Dvm644 README.rst -t "$pkgdir/usr/share/doc/$pkgname/"
	# install -Dm644 _build/google-cloud-bigquery.1 -t "$pkgdir/usr/share/man/man1/"
	local _site="$(python -c 'import site; print(site.getsitepackages()[0])')"
	install -dv "$pkgdir/usr/share/licenses/$pkgname/"
	ln -sv \
		"$_site/${_pkgname//-/_}-$pkgver.dist-info/LICENSE" \
		"$pkgdir/usr/share/licenses/$pkgname/"
}