summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5da069fa6004daf5a48bb5b7475ab3ce20b1269c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Maintainer: Aleksandar Trifunović <akstrfn at gmail dot com>
# Contributor: Tiago de Paula Peixoto <tiago@skewed.de>

_pkgname=python-graph-tool
pkgname=python-graph-tool-git
pkgver=release.2.27.r7.g41bae98c
pkgrel=1
pkgdesc='A Python module for manipulation and statistical analysis of graphs'
arch=('i686' 'x86_64')
url='https://graph-tool.skewed.de'
license=(GPL3)
depends=(cgal cairomm python-scipy python-numpy python-cairo)
makedepends=(boost sparsehash autoconf-archive)
optdepends=('graphviz: graph layout'
            'python-matplotlib: graph drawing')
provides=("$_pkgname")
conflicts=(python3-graph-tool)
replaces=(python3-graph-tool)
options=(!libtool)
source=("$pkgname::git+https://git.skewed.de/count0/graph-tool.git")
sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$pkgname"
  ./autogen.sh
  ./configure --enable-openmp --prefix=/usr --docdir="/usr/share/doc/$_pkgname"
  make -j 1  # most users will be surprised with the high memory usage required for parallel builds
}

check() {
  cd "$pkgname"
  make check
}

package() {
  cd "$pkgname"
  make DESTDIR="$pkgdir/" install
}