blob: 40f22290274016756b3c4326472d38b7077093be (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
|
# Maintainer: Antonio Bartalesi <antonio.bartalesi@gmail.com>
_name=guidata
pkgname="python-${_name}"
pkgver=3.14.2
pkgrel=1
pkgdesc="guidata: Automatic GUI generation for easy dataset editing and display with Python"
arch=("any")
url="https://github.com/PlotPyStack/${_name}"
license=("BSD-3-Clause")
depends=(python python-h5py python-numpy python-qtpy python-requests python-tomli python-pandas python-beautifulsoup4 python-pillow python-matplotlib)
makedepends=(python-build python-installer python-wheel python-pydantic)
optdepends=(
"spyder: GUI-based test launcher, dict/array editor"
"python-sphinx: for building documentation"
"python-pytest: for running tests"
)
source=("$_name-$pkgver.tar.gz::https://github.com/PlotPyStack/${_name}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=("e69388c9831c164f71e918cde0193a7e37cbbfa9b896a72b7b5d75020381c51d")
build() {
cd "${_name}-${pkgver}"
python -m build --wheel --no-isolation
}
package() {
cd "${_name}-${pkgver}"
python -m installer --destdir="${pkgdir}" dist/*.whl
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
}
|