blob: db19a1d66644791cfae3a7f4d7ed0c7df546f600 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: a821
# Contributor: lilydjwg <lilydjwg@gmail.com>
pkgname=python-http-parser-git
pkgver=0.9.0.r3.gd6ce4b5
epoch=1
pkgrel=1
pkgdesc="HTTP request/response parser for python in C"
arch=('x86_64' 'i686')
url="https://github.com/benoitc/http-parser"
license=('MIT')
depends=('python')
makedepends=('git' 'python-setuptools' 'cython')
checkdepends=('python-pytest')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
md5sums=(SKIP)
source=("${pkgname}::git+${url}")
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/-/.r/;s/-/./g'
}
build() {
cd "$pkgname"
cython -o http_parser/parser.c http_parser/parser.pyx
python setup.py build
}
check() {
cd "$pkgname"
_pyver=$(python -c 'import sys; print(*sys.version_info[:2], sep="")')
PYTHONPATH="$PWD/build/lib.linux-x86_64-cpython-$_pyver/" pytest testing
}
package() {
cd "$pkgname"
python setup.py install --root="$pkgdir/" --optimize=1
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|