blob: edb03025c85711880996ef188ccf996ecd97d60e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: Carl Smedstad <carsme@archlinux.org>
pkgname=python-instructor
_pkgname=${pkgname#python-}
pkgver=1.2.5
pkgrel=1
pkgdesc="Structured outputs for LLMs"
arch=(any)
url="https://github.com/jxnl/instructor"
license=(MIT)
depends=(
python
python-aiohttp
python-docstring-parser
python-httpx
python-openai
python-pydantic
python-pydantic-core
python-regex
python-rich
python-tenacity
python-typer
python-typing_extensions
)
makedepends=(
python-build
python-installer
python-poetry
python-wheel
)
checkdepends=(
python-anthropic
python-cohere
python-pytest
)
optdepends=(
'python-anthropic: support for Anthropic models'
'python-cohere: support for Cohere models'
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
sha256sums=('ccbbcc62a15db2e38c2e446417bc844d58e702e45e76be3410e19c908bdb4945')
_archive="$_pkgname-$pkgver"
build() {
cd "$_archive"
python -m build --wheel --no-isolation
}
check() {
cd "$_archive"
rm -rf tmp_install
python -m installer --destdir=tmp_install dist/*.whl
local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
export PYTHONPATH="$PWD/tmp_install/$site_packages:$PYTHONPATH"
# Deselect/ignore tests requiring valid API keys to OpenAI or Anthropic,
# below is a mock one.
export OPENAI_API_KEY=sk-dBAe8c5a9bc4294cca9bed292cd61e0ff9030bB94647adfb
pytest \
--deselect tests/dsl/test_partial.py \
--deselect tests/llm/test_anthropic/evals/test_simple.py \
--deselect tests/llm/test_new_client.py \
--ignore tests/llm/test_openai
}
package() {
cd "$_archive"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|