blob: e68ce7d25e960a25d7dcd605abf7c8294a4b05d7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: jyantis <yantis@yantis.net>
pkgname=python-isbnlib-git
pkgver=3.5.6.r476.46f95b2
pkgrel=2
pkgdesc='Python 3 library to extract, clean, transform, hyphenate and get metadata for ISBN strings (based on isbntools)'
arch=('any')
url='https://github.com/xlcnd/isbnlib'
license=('LGPL')
depends=('python')
source=('git+https://github.com/xlcnd/isbnlib.git')
sha256sums=('SKIP')
makedepends=('git' 'python-setuptools')
provides=('python-isbnlib')
conflicts=('python-isbnlib')
pkgver() {
cd isbnlib
printf "%s." "$(grep -R "__version__ =" isbnlib/__init__.py | awk -F\' '{print $2}')"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd isbnlib
python setup.py build
}
check() {
cd isbnlib
python setup.py test --verbose
}
package() {
cd isbnlib
# We don't need anything related to git in the package
rm -rf .git*
python setup.py install --root="${pkgdir}" --optimize=1
# Install License
install -D -m644 LICENSE-LGPL.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
# Install Documentation
install -D -m644 README.rst "${pkgdir}/usr/share/doc/${pkgname}/README.rst"
}
# vim:set ts=2 sw=2 et:
|