PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

_pkgname="python-isr"
pkgname="${_pkgname}-git"
pkgver=r151.3d07905
pkgrel=1
pkgdesc="Super-scale your images and run experiments with Residual Dense and Adversarial Networks."
arch=("any")
url="https://github.com/idealo/image-super-resolution"
license=("Apache")
_pydeps=("numpy" "imageio" "pyaml" "tensorflow")
depends=("python" ${_pydeps[@]/#/python-})
makedepends=("git" "python-setuptools")
provides=("isr")
conflicts=("isr" "python-isr")
source=("git+${url}.git")
sha256sums=('SKIP')
_srcname="image-super-resolution"

pkgver() {
    cd "${srcdir}/${_srcname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "${srcdir}/${_srcname}"
    python setup.py build
}

package() {
    cd "${srcdir}/${_srcname}"
    python setup.py install --root="${pkgdir}/" --prefix=/usr --optimize=1 --skip-build
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}"
}