blob: c00e3de191911f14362bb716882c0f4d06c75f5e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- sh -*-
pkgname='python-jh2-git'
_pkgname="${pkgname/-git/}"
_srcname="${_pkgname/python-/}"
pkgver=5.0.3.r0.g66b5a7d
pkgrel=4
pkgdesc='HTTP/2 State-Machine based protocol implementation (built from latest commit)'
arch=('aarch64' 'x86_64')
url='https://github.com/jawah/h2'
license=('MIT') # SPDX-License-Identifier: MIT
depends=(
'gcc-libs'
'glibc'
'python>=3.7'
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-maturin'
'python-setuptools'
'python-wheel'
)
source=("$_srcname::git+$url.git")
provides=("$_pkgname")
conflicts=("$_pkgname")
sha256sums=('SKIP')
options=('lto')
pkgver() {
cd "$_srcname"
git describe --tags --long \
| sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_srcname"
# RFC-0023
# 🔗 https://rfc.archlinux.page/0023-pack-relative-relocs/
#
# ld(1) says: “Supported for i386 and x86-64.”
case "Z${CARCH:-unknown}" in
'Zx86_64' | 'Zi386' )
export LDFLAGS="$LDFLAGS -Wl,-z,pack-relative-relocs"
;;
* ) : pass ;;
esac
python -m build --wheel --no-isolation
}
package() {
cd "$_srcname"
python -m installer --destdir="$pkgdir" dist/*.whl
install -vDm0644 -t "$pkgdir/usr/share/doc/$pkgname/" \
{CHANGELOG,README}.rst
install -vDm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" \
LICENSE
}
# eof
|