PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: bemxio <bemxiov at protonmail dot com>

pkgname=python-jumpcutter
_name=${pkgname#python-}

pkgdesc="Jumpcut silent parts of your videos automagically"

pkgver=0.1.6
pkgrel=2

arch=(any)

url="https://pypi.org/project/jumpcutter/"
license=("MIT")

depends=(python python-moviepy python-tqdm)
makedepends=(python-build python-installer python-wheel)

source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
md5sums=("664185983281e283bdd36ca1a276af3c")

build() {
	# move to the source directory
	cd "${_name}-${pkgver}"

	# build the package
	python -m build --wheel --no-isolation
}

package() {
	# move to the source directory
	cd "${_name}-${pkgver}"

	# package the files
	python -m installer --destdir="${pkgdir}" dist/*.whl

	# bundle the license in the package
	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}