PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27

# Maintainer: devome <evinedeng@hotmail.com>
# Contributor: txtsd <aur.archlinux@ihavea.quest>

_pkgname=langchain
pkgname="python-${_pkgname}"
pkgver=0.3.7
pkgrel=1
pkgdesc='Building applications with LLMs through composability'
arch=('any')
url='https://github.com/langchain-ai/langchain'
license=('MIT')
depends=("python-aiohttp" "python-langchain-core" "python-langchain-text-splitters" "python-langsmith" "python-numpy" "python-pydantic"
         "python-requests" "python-sqlalchemy" "python-tenacity" "python-yaml" )
makedepends=('python-build' 'python-installer' 'python-wheel' 'python-poetry-core')
source=("${_pkgname}-${pkgver}.tar.gz::https://files.pythonhosted.org/packages/source/${_pkgname::1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
sha256sums=('2e4f83bf794ba38562f7ba0ede8171d7e28a583c0cec6f8595cfe72147d336b2')

build() {
    cd "${_pkgname}-${pkgver}"
    python -m build --wheel --no-isolation
}

package() {
    cd "${_pkgname}-${pkgver}"
    python -m installer --destdir="${pkgdir}" dist/*.whl
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}