summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6cfaeb513b1610e792ee95530a613e43cbae54d0 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: xiretza <xiretza+aur@xiretza.xyz>

_srcname=litejesd204b
pkgname="python-$_srcname-git"
pkgver=2020.08.r1.g1e88fa8
pkgrel=1
pkgdesc="A small footprint and configurable JESD204B core for LiteX"
arch=(any)
url="https://github.com/enjoy-digital/litejesd204b"
license=('MIT')
depends=(python python-migen python-litex)
makedepends=(git python-setuptools)
provides=("${pkgname%%-git}=$pkgver")
conflicts=("${pkgname%%-git}")
replaces=("$_srcname-git")
source=("git+$url")
sha256sums=('SKIP')

pkgver() {
  cd "$_srcname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$_srcname"
  python setup.py build
}

package() {
  cd "$_srcname"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set et ts=2 syntax=PKGBUILD: