PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Maintainer: Frederik “Freso” S. Olesen <freso.dk@gmail.com>

pkgbase=python-mbdata-git
_pkgbase=${pkgbase%-git}
_name=${_pkgbase#python-}
pkgname=($pkgbase ${pkgbase/python-/python2-})
pkgver=2017.06.02.r23.g55a2372
pkgrel=1
pkgdesc='MusicBrainz database tools for Python'
url="https://github.com/lalinsky/$_name"
arch=('any')
license=('MIT')
makedepends=('python-setuptools' 'python2-setuptools' 'git')
source=("git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd python3
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

prepare() {
  cp -a $_name python2
  mv $_name python3
}

build() {
  pushd python3
  python3 setup.py build
  popd

  pushd python2
  python2 setup.py build
}

package_python-mbdata-git() {
  depends=(python python-psycopg2 python-six)
  provides=(${_pkgbase})
  conflicts=(${_pkgbase})

  cd python3
  python3 setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_pkgbase/LICENSE"
  install -d "$pkgdir/usr/share/doc/$_pkgbase"
  install -m644 -t "$pkgdir/usr/share/doc/$_pkgbase" README.rst CHANGELOG.rst settings.py.sample mbslave.conf.default
}

package_python2-mbdata-git() {
  depends=(python2 python2-psycopg2 python2-six)
  provides=(${_pkgbase/python-/python2-})
  conflicts=(${_pkgbase/python-/python2-})

  cd python2
  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${_pkgbase/python-/python2-}/LICENSE"
  install -d "$pkgdir/usr/share/doc/${_pkgbase/python-/python2-}"
  install -m644 -t "$pkgdir/usr/share/doc/${_pkgbase/python-/python2-}" README.rst CHANGELOG.rst settings.py.sample mbslave.conf.default
  # `mbslave` is provided by python-mbdata-git (for Python 3); no sense in duplicating
  rm -rf "$pkgdir/usr/bin"
}