blob: 05aa8e24fdb987945316cf42c91cad98ad5254c1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
_pkgname=mmcv
pkgname=(python-mmcv python-mmcv-full)
pkgver=1.1.6
pkgrel=1
pkgdesc='OpenMMLab Computer Vision Foundation'
arch=('x86_64')
url='https://github.com/open-mmlab/mmcv'
license=('Apache')
depends=(
python-addict
python-lmdb
python-pillow
)
makedepends=(
cuda
cython
python-pytorch-cuda
python-setuptools
)
optdepends=(
"opencv: optional image backend"
)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/open-mmlab/mmcv/archive/v${pkgver}.tar.gz")
sha512sums=('3e8faebd68bd5f3b40f8495c41963db4ed0689e97a203737b3eff46dbd8f20932e38da2381302622baaa44cc7574920ffbfefc67083d59765a7e2661c86d3a78')
build() {
cp -a "${_pkgname}-${pkgver}" "${_pkgname}-full-${pkgver}"
cd "${srcdir}/${_pkgname}-${pkgver}"
python setup.py build
cd "${srcdir}/${_pkgname}-full-${pkgver}"
TORCH_CUDA_ARCH_LIST="5.2;5.3;6.0;6.0+PTX;6.1;6.1+PTX;6.2;6.2+PTX;7.0;7.0+PTX;7.2;7.2+PTX;7.5;7.5+PTX;8.0;8.0+PTX" \
MMCV_WITH_OPS=1 FORCE_CUDA=1 python setup.py build
}
package_python-mmcv() {
pkgdesc+="(lite version, without cuda ops)"
depends+=(python-pytorch)
cd "${_pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}
package_python-mmcv-full() {
pkgdesc+=" (full version, with full features, include cuda ops)"
depends+=(cuda python-pytorch-cuda)
provides=(python-mmcv=${pkgver})
conflicts=(python-mmcv)
cd "${_pkgname}-full-${pkgver}"
python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}
# vim:set ts=2 sw=2 et:
|