blob: fb1bbc35fd5d3714217b264c0b4db43a3298cba1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
_pkgname=mmdetection
pkgname=python-mmdetection
pkgver=2.3.0
pkgrel=4
pkgdesc='OpenMMLab Detection Toolbox and Benchmark'
arch=('any')
url='https://github.com/open-mmlab/mmdetection'
license=('Apache')
depends=(
python-mmcv
python-numpy
python-pycocotools-openmm
python-pytorch
python-terminaltables
python-torchvision
)
makedepends=(
python-setuptools
)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/open-mmlab/mmdetection/archive/v${pkgver}.tar.gz"
"0001-fix-ClassBalancedDataset.patch::https://github.com/open-mmlab/mmdetection/pull/3577.patch")
sha512sums=('80a865d65f42e886e6a358702dc49d9df39f700069047d287e70647e81dbcf2b9d1fd27b2b01087b738b96a25c2251618dd8f4d59b7a428c621f6fbff79c6e02'
'1bf79e840d7d38c781163699559fa47d9881e6615f316c8a188244fce1660a22d2255bc07956aacb929d1b0abaff3d2c1a636dfcabedf4de06a43eedd216fe2a')
prepare() {
cd "${_pkgname}-${pkgver}"
patch -p1 -i ../0001-fix-ClassBalancedDataset.patch
# relax mmcv version requirement
sed -i '23,26d' "mmdet/__init__.py"
}
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
python setup.py build
}
package() {
cd "${_pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}
# vim:set ts=2 sw=2 et:
|