blob: bb06a142dd286b771918135d05f2c91dfe838a08 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Clemens Brunner <clemens dot brunner at gmail dot com>
pkgname=python-mnelab
_name=${pkgname#python-}
pkgver=1.4.4
pkgrel=1
pkgdesc="Graphical user interface (GUI) for MNE, a Python package for EEG/MEG analysis"
arch=('any')
url="https://github.com/cbrnr/mnelab"
license=('BSD-3-Clause')
depends=(
'pyside6'
'python'
'python-autoreject'
'python-black'
'python-edfio'
'python-isort'
'python-matplotlib'
'python-mne'
'python-mne-qt-browser'
'python-numpy'
'python-onnx'
'python-picard'
'python-pybv'
'python-pybvrf'
'python-pyxdf'
'python-scikit-learn'
'python-scipy'
'qt6-svg'
)
makedepends=('python-build' 'python-installer' 'python-uv-build')
source=(
"https://files.pythonhosted.org/packages/source/${_name:0:1}/$_name/$_name-$pkgver.tar.gz"
"mnelab.desktop"
"mnelab-mimetypes.xml"
)
sha256sums=('5e0cbd02dc98e4b265cadbd4f9abd4f05e882b524c02552c36fb6e438579b8c9'
'90465ed1dcd28013a24a9410d9ea7529e9a94e58325d54d57dacf7c0552ec3ae'
'566cccf86be39eed374a3cfa3905945c9aa60e553b73c4758c2c66d46184c977')
prepare() {
cd "$srcdir/$_name-$pkgver"
# Relax uv_build version constraint to allow Arch's current version
sed -i -E 's/(uv_build\s*>=?\s*0\.10\.9,\s*<\s*)0\.11\.0/\10.12.0/' pyproject.toml
}
build() {
cd "$srcdir/$_name-$pkgver"
python -m build --wheel --no-isolation
}
package() {
cd "$srcdir/$_name-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 "$srcdir/mnelab.desktop" "$pkgdir/usr/share/applications/mnelab.desktop"
install -Dm644 "$srcdir/mnelab-mimetypes.xml" "$pkgdir/usr/share/mime/packages/mnelab.xml"
install -Dm644 "src/mnelab/icons/mnelab-logo.svg" \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/mnelab.svg"
install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|