blob: cc2df40092cdfe9611e8a6d744c99518a8c5f9a4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: William Turner <willtur.will@gmail.com>
pkgbase=python-mutatormath
pkgname=(python-mutatormath python2-mutatormath)
_pkgname=MutatorMath
pkgver=2.1.0
pkgrel=1
pkgdesc='A library for the calculation of piecewise linear interpolations in n-dimensions with any number of masters.'
arch=('any')
url='https://github.com/LettError/MutatorMath'
license=('BSD')
depends=('python' 'python-fonttools' 'python-ufolib' 'python-defcon' 'python-fontmath'
'python2' 'python2-fonttools' 'python2-ufolib' 'python2-defcon' 'python2-fontmath')
makedepends=('python-pip' 'python2-pip')
options=(!emptydirs)
source=("https://files.pythonhosted.org/packages/py2.py3/${_pkgname:0:1}/${_pkgname}/${_pkgname}-${pkgver}-py2.py3-none-any.whl")
sha256sums=('46bb5209af53ee245d0e6cb9fe47f4f5718db7c158136715cd28494b239395c5')
package_python-mutatormath() {
depends=('python' 'python-fonttools' 'python-ufolib' 'python-defcon' 'python-fontmath')
provides=('python-mutatormath')
cd "${srcdir}"
# install the wheel
PIP_CONFIG_FILE=/dev/null pip install \
--isolated \
--root="${pkgdir}" \
--ignore-installed \
--no-deps \
${_pkgname}-${pkgver}-py2.py3-none-any.whl
# compile to pyo
python -O -m compileall "${pkgdir}"
}
package_python2-mutatormath() {
depends=('python2' 'python2-fonttools' 'python2-ufolib' 'python2-defcon' 'python2-fontmath')
provides=('python2-mutatormath')
cd "${srcdir}"
# install the wheel
PIP_CONFIG_FILE=/dev/null pip2 install \
--isolated \
--root="${pkgdir}" \
--ignore-installed \
--no-deps \
${_pkgname}-${pkgver}-py2.py3-none-any.whl
# compile to pyo
python2 -O -m compileall "${pkgdir}"
}
|