blob: 1f992b09aa9996e1adb402aac304fb90d1afc6f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Josh Holmer <jholmer.in@gmail.com>
_plug=muxtools
pkgname=python-${_plug}-git
pkgver=0.1.0.7.g4b1ca0d
pkgrel=1
pkgdesc="Python Package: ${_plug} (GIT version)"
arch=('any')
url='https://github.com/Jaded-Encoding-Thaumaturgy/muxtools'
license=('MIT')
depends=(
'python-requests'
# 'python-fontcollector' # package doesn't exist
# 'python-ass' # package is broken
# 'python-wget' # package doesn't exist
'python-py7zr'
'python-pymediainfo'
'python-rich'
'python-pyparsebluray-git'
)
makedepends=(
'git'
'python-build'
'python-wheel'
'python-installer'
'python-setuptools'
)
provides=("python-${_plug}")
conflicts=("python-${_plug}")
source=("${_plug}::git+https://github.com/Jaded-Encoding-Thaumaturgy/muxtools.git")
sha256sums=('SKIP')
pkgver() {
cd "${_plug}"
echo "$(git describe --long --tags | tr - . | tr -d v)"
}
build() {
cd "${_plug}"
python -m build --wheel --no-isolation
}
package() {
cd "${_plug}"
python -m installer --destdir="${pkgdir}" dist/*.whl
install -Dm644 README.md "${pkgdir}/usr/share/doc/vapoursynth/tools/${_plug}/README.md"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|