blob: 32086938bb330c25fbc3be641e52350dfc7dca96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: George Rawlinson <george@rawlinson.net.nz>
# Contributor: Pochang Chen <johnchen902@gmail.com>
pkgname=python-nclib-git
_pkgname="${pkgname%-git}"
_pkg="${_pkgname#python-}"
pkgver=1.0.2.r1.ge80f2cc
pkgrel=1
pkgdesc="Netcat as a library"
license=('MIT')
arch=('any')
url='https://github.com/rhelmot/nclib'
depends=('python')
makedepends=('git' 'python-build' 'python-installer' 'python-setuptools' 'python-wheel')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("$_pkgname::git+$url")
sha256sums=('SKIP')
pkgver() {
git -C "$_pkgname" describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
}
build() {
cd "$_pkgname"
python -m build --wheel --no-isolation
}
package() {
cd "$_pkgname"
python -m installer --destdir="$pkgdir/" dist/*.whl
local _site="$(python -c 'import site; print(site.getsitepackages()[0])')"
install -dv "$pkgdir/usr/share/licenses/$pkgname/"
ln -sv "$_site/$_pkg-${pkgver%.r*}.dist-info/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/"
}
|