blob: 2978f0be092707ea028b6ab60cbfbc6aef3cd3e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Chris Warrick <aur@chriswarrick.com>
# Contributor: shmilee <echo c2htaWxlZS56anVAZ21haWwuY29tCg==|base64 -d>
pkgbase=python-nikola
_pyname=Nikola
_pynamel=nikola
pkgname=('python-nikola' 'python-nikola-doc')
pkgver=7.8.10
pkgrel=1
pkgdesc='A modular, fast, simple, static website generator.'
arch=('any')
url='https://getnikola.com/'
license=('MIT')
options=(!emptydirs)
makedepends=('python' 'python-doit' 'python-pygments' 'python-pillow'
'python-docutils' 'python-mako' 'python-unidecode' 'python-lxml'
'python-yapsy>=1.11.223' 'python-pyrss2gen' 'python-dateutil' 'python-logbook'
'python-blinker' 'python-natsort' 'python-setuptools'
'python-requests' 'python-husl' 'python-piexif' 'python-markdown')
source=("https://pypi.io/packages/source/N/Nikola/${_pyname}-${pkgver}.tar.gz")
md5sums=('a3a4e7f5417f6ce19b6edbbe8b778131')
build() {
cd "${srcdir}/${_pyname}-${pkgver}"
}
package_python-nikola() {
depends=('python' 'python-doit' 'python-pygments' 'python-pillow'
'python-docutils' 'python-mako' 'python-unidecode' 'python-lxml'
'python-yapsy>=1.11.223' 'python-pyrss2gen' 'python-dateutil' 'python-logbook'
'python-blinker' 'python-natsort' 'python-setuptools'
'python-requests' 'python-husl' 'python-piexif' 'python-markdown')
optdepends=('python-jinja: for Jinja2 themes'
'python-pyphen>=0.9.1: for hyphenation'
'python-pygal=1.7.0: for SVG graph plotting'
'python-typogrify>=2.0.4: for typographical enhancements'
'python-webassets: for bundling assets'
'ipython-notebook: for ipynb support'
'ipython: for ipynb support'
'python-ghp-import>=0.4.1: for uploading to GitHub Pages'
'python-micawber: for embedding media in posts'
'python-phpserialize: for WordPress imports'
'python-ws4py: for nikola auto'
'python-watchdog: for nikola auto')
conflicts=('python-nikola-git')
cd "${srcdir}/${_pyname}-${pkgver}"
python3 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
ln -s ${_pynamel} "${pkgdir}/usr/bin/${_pynamel}3"
rm -rf "${pkgdir}/usr/share"
}
package_python-nikola-doc(){
pkgdesc="Nikola documentation, license and man page"
conflicts=('python-nikola-doc-git')
cd "${srcdir}/${_pyname}-${pkgver}"
install -d -m755 "${pkgdir}/usr/share"/{doc/${pkgbase},man/man1,licenses/${pkgbase}}
install -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgbase}/LICENSE"
cd "docs/"
install -m644 man/nikola.1.gz "${pkgdir}/usr/share/man/man1/nikola.1.gz"
install -m644 manual.txt "${pkgdir}/usr/share/doc/${pkgbase}/manual.txt"
install -m644 theming.txt "${pkgdir}/usr/share/doc/${pkgbase}/theming.txt"
install -m644 extending.txt "${pkgdir}/usr/share/doc/${pkgbase}/extending.txt"
}
# vim:set ts=2 sw=2 et:
|