blob: 6f23622984a2bea5a89a6636c77d16bf9c77ac7b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Michael Stegeman <mstegeman@mozilla.com>
pkgbase=python-nnpy
pkgname=('python-nnpy' 'python2-nnpy')
pkgver=1.4.2
pkgrel=1
pkgdesc='nanomsg bindings for Python'
arch=('x86_64')
url='https://pypi.org/project/nnpy/'
license=('MIT')
makedepends=('nanomsg' 'python-cffi' 'python-setuptools' 'python2-cffi' 'python2-setuptools')
source=(
"${pkgbase}-${pkgver}.tar.gz::https://github.com/nanomsg/nnpy/archive/${pkgver}.tar.gz"
)
sha256sums=(
'fcfc4115429cae1872a51abe94bb01e2de6d851c5ce82d415d85f0e60a128549'
)
prepare() {
cp -a nnpy-${pkgver}{,-py2}
find "nnpy-${pkgver}-py2" -name \*.py -exec sed -i '1s/python$/&2/' {} +
}
build() {
cd "${srcdir}/nnpy-${pkgver}"
python setup.py build
cd "${srcdir}/nnpy-${pkgver}-py2"
python2 setup.py build
}
package_python-nnpy() {
depends=('nanomsg' 'python-cffi')
cd "${srcdir}/nnpy-${pkgver}"
python setup.py install --root="$pkgdir" --optimize=1
}
package_python2-nnpy() {
depends=('nanomsg' 'python2-cffi')
cd "${srcdir}/nnpy-${pkgver}-py2"
python2 setup.py install --root="$pkgdir" --optimize=1
}
# vim:set ts=2 sw=2 et ft=sh:
|