blob: 024c6e3cd65d4cca4d8d03a7bd83b07bd3f90c69 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Blair Bonnett <blair.bonnett@gmail.com>
# Contributor: Maikel Wever <maikelwever@gmail.com>
pkgname=python-numpy-stl
pkgver=3.1.1
pkgrel=1
pkgdesc="Library to make working with STL files (and 3D objects in general) fast and easy"
url="https://github.com/WoLpH/numpy-stl/"
license=('BSD')
depends=('python' 'python-numpy' 'python-utils')
makedepends=('cython' 'python-build' 'python-installer' 'python-setuptools' 'python-wheel')
checkdepends=('python-pytest' 'python-pytest-cov' 'xorg-server-xvfb')
source=(
"numpy-stl-v${pkgver}.tar.gz::https://github.com/WoLpH/numpy-stl/archive/v${pkgver}.tar.gz"
)
sha256sums=(
'6e2765e34da0c5873402d04a3ae73f2f1a3a2a3b97eaae7c41e8eb4e083e9834'
)
arch=('x86_64')
build() {
cd "$srcdir/numpy-stl-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "$srcdir/numpy-stl-$pkgver"
local python_version=$(python -c 'import sys; print("".join(map(str, sys.version_info[:2])))')
PYTHONPATH="$PWD/build/lib.linux-$CARCH-cpython-${python_version}" pytest \
-vv tests --cov-fail-under=50
}
package() {
cd "$srcdir/numpy-stl-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et:
|