blob: 0e79674f532f6d57f08b436cdb1cc3bf8ffe5cfe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
pkgname=python-nvidia-dali
_pkgname=dali
pkgver=0.26.0
pkgrel=1
pkgdesc='A library containing both highly optimized building blocks and an execution engine for data pre-processing in deep learning applications'
arch=('x86_64')
url='https://github.com/NVIDIA/DALI'
license=('Apache')
depends=(
'cuda'
'lmdb'
'opencv'
'protobuf'
'python'
)
makedepends=(
'cmake'
'git'
'python-setuptools'
)
source=("${pkgname}::git+https://github.com/NVIDIA/DALI.git#tag=v${pkgver}")
sha512sums=('SKIP')
get_pyver() {
python -c 'import sys; print(str(sys.version_info[0]) + "." + str(sys.version_info[1]))'
}
prepare() {
cd "${srcdir}/${pkgname}"
git submodule update --init --recursive
}
build() {
mkdir "${srcdir}/${pkgname}/build"
cd "${srcdir}/${pkgname}/build"
cmake \
-DBUILD_LMDB:BOOL=ON \
-DCMAKE_BUILD_TYPE:String=Release \
-DCMAKE_CUDA_HOST_COMPILER=/opt/cuda/bin/g++ \
-DCMAKE_INSTALL_PREFIX:PATH=/usr \
-DCMAKE_SKIP_RPATH:BOOL=ON \
-DProtobuf_USE_STATIC_LIBS:BOOL=OFF \
..
make
cd 'dali/python'
python setup.py build
}
package() {
cd "${srcdir}/${pkgname}/build"
make DESTDIR="${pkgdir}" install
cd 'dali/python'
python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
# create softlink to save space
ln -sf "/usr/lib/python$(get_pyver)/site-packages/nvidia/dali/libdali.so" "${pkgdir}/usr/lib/libdali.so"
ln -sf "/usr/lib/python$(get_pyver)/site-packages/nvidia/dali/libdali_core.so" "${pkgdir}/usr/lib/libdali_core.so"
ln -sf "/usr/lib/python$(get_pyver)/site-packages/nvidia/dali/libdali_kernels.so" "${pkgdir}/usr/lib/libdali_kernels.so"
ln -sf "/usr/lib/python$(get_pyver)/site-packages/nvidia/dali/libdali_operators.so" "${pkgdir}/usr/lib/libdali_operators.so"
}
# vim:set ts=2 sw=2 et:
|