blob: ba92cba75de05c41926fd169569c823ec59be535 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Grey Christoforo <first name [at] last name [dot] net>
pkgname=python-occ
pkgver=7.4.1
pkgrel=1
pkgdesc="A python library whose purpose is to provide 3D modeling features"
url="https://github.com/tpaviot/pythonocc-core"
arch=(x86_64)
license=(LGPL3)
makedepends=(cmake swig)
depends=(opencascade python libxi libxmu)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/tpaviot/pythonocc-core/archive/${pkgver}.tar.gz")
sha256sums=('6d62002244a0e7f4e5c1ad590d332a60601c44b2501ad017361443b54371e667')
prepare() {
cd pythonocc-core-${pkgver}
mkdir -p build
cd build
cmake ..
}
build() {
cd pythonocc-core-${pkgver}/build
make
}
check(){
cd pythonocc-core-${pkgver}/build
# yeah, this is a hack, but I can't easily get to a testable state otherwise
mkdir tmp
make DESTDIR=tmp install
_i_dir="$(python -c 'import sys; print(sys.path[-1])')"
PYTHONPATH="tmp/${_i_dir}" python "${srcdir}/pythonocc-core-${pkgver}/test/run_tests.py"
}
package() {
cd pythonocc-core-${pkgver}/build
make DESTDIR="${pkgdir}" install
install -Dm644 "${srcdir}/pythonocc-core-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ts=2 sw=2 et:
|