PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# Maintainer: Daniel Bermond <dbermond@archlinux.org>

pkgname=python-openvino-telemetry-git
pkgver=r58.g4a7e3b6
pkgrel=1
pkgdesc='Pythno library for sending statistics data from the OpenVINO toolkit components (git version)'
arch=('any')
url='https://github.com/openvinotoolkit/telemetry/'
license=('Apache-2.0')
depends=('python')
makedepends=('git' 'python-build' 'python-installer' 'python-setuptools' 'python-wheel')
provides=('openvino-telemetry')
conflicts=('openvino-telemetry')
source=('openvino-telemetry'::'git+https://github.com/openvinotoolkit/telemetry.git')
sha256sums=('SKIP')

pkgver() {
    cd openvino-telemetry
    ( set -o pipefail
        git describe --long --abbrev='7' 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//' ||
        printf 'r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short='7' HEAD)"
    )
}

build() {
    cd openvino-telemetry
    python -m build --wheel --no-isolation
}

package() {
    python -m installer --destdir="$pkgdir" openvino-telemetry/dist/*.whl
}