blob: 7f3c301807f42be88653303a06a716e40fa8d1a8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: Michael M. Tung <mtung at mat dot upv dot es>
_pyname=panflute
pkgname=python-$_pyname-git
pkgver=v2.3.0.r0.g1c5447d
pkgrel=1
pkgdesc='A Pythonic alternative to John MacFarlane’s pandocfilters'
arch=(any)
url="https://github.com/sergiocorreia/$_pyname"
license=(BSD-3-Clause)
_pydeps=(click
yaml)
depends=(pandoc
python
"${_pydeps[@]/#/python-}")
makedepends=(git
python-{build,installer,wheel}
python-setuptools)
_pycheckdeps=(pandocfilters
pytest
pytest-cov)
checkdepends=("${_pycheckdeps[@]/#/python-}")
provides=("${pkgname%-git}=$pkgver" "pandoc-$_pyname=$pkgver")
conflicts=("${pkgname%-git}" "pandoc-$_pyname")
replaces=("pandoc-$_pyname-git")
source=("$pkgname::git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --long --always --tags --abbrev=7 HEAD |
sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$pkgname"
python -m build -wn
}
check() {
cd "$pkgname"
PYTHONPATH="$PWD" pytest \
--deselect tests/test_panfl.py::test_pandoc_call
}
package() {
cd "$pkgname"
python -m installer -d "$pkgdir" dist/*.whl
}
|