blob: 6558b95e87f5e301084e0665abb4c7abc0b4cdc2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
pkgbase=python-parallax
pkgname=('python-parallax' 'python2-parallax')
pkgver=1.0.3
pkgrel=2
pkgdesc="Execute commands and copy files over SSH to multiple machines at once"
arch=('any')
license=('BSD')
url="https://github.com/krig/parallax"
makedepends=('python-setuptools' 'python2-setuptools')
source=("$url/archive/$pkgver.tar.gz")
sha256sums=('6a0199ea1c3fedd84ea25ab9a1a2c7b7a30e6484331dc33b03ee4e23b5f7b239')
prepare() {
cd "$srcdir"
cp -a parallax-$pkgver python-parallax-$pkgver
cp -a parallax-$pkgver python2-parallax-$pkgver
}
build() {
cd "$srcdir"/python-parallax-$pkgver
python setup.py build
cd "$srcdir"/python2-parallax-$pkgver
python2 setup.py build
}
package_python-parallax() {
depends=('python')
cd "$srcdir"/$pkgname-$pkgver
python setup.py install --root="$pkgdir" --optimize=1 --skip-build
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
package_python2-parallax() {
depends=('python2')
cd "$srcdir"/$pkgname-$pkgver
python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
mv "$pkgdir/usr/bin/parallax-askpass" "$pkgdir/usr/bin/parallax-askpass2"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim: set sw=2 et:
|