PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Wojciech Szymecki <w.szymecki-at-g;mail-com>
_name="parsimonious"

pkgbase="python-${_name}"
pkgname=("python-${_name}" "python2-${_name}")
pkgver=0.8.0
pkgrel=1
arch=('any')
url="https://pypi.python.org/pypi/${_name}/${pkgver}"
license=('MIT')
makedepends=('python-setuptools' 'python2-setuptools')
pkgdesc="Fast parser based on parsing expression grammars (PEGs)"
source=("https://files.pythonhosted.org/packages/source/${_name:0:1}/${_name}/${_name}-${pkgver}.tar.gz")
sha256sums=('ae0869d72a6e57703f24313a5f5748e73ebff836e6fe8b3ddf34ea0dc00d086b')

prepare() {
    cp -r "${srcdir}/${_name}-${pkgver}" "${srcdir}/${_name}-${pkgver}-python2"
}

build() {
    cd "${srcdir}/${_name}-${pkgver}"
    python3 setup.py build
    cd "${srcdir}/${_name}-${pkgver}-python2"
    python2 setup.py build
}

package_python-parsimonious() {
  pkgdesc="Fast parser based on parsing expression grammars (PEGs) - Python 3 version."
  depends=('python>=3.3')

  cd "${srcdir}/${_name}-${pkgver}"

  python3 setup.py install --skip-build --root="${pkgdir}" --optimize=1
  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_python2-parsimonious() {
  pkgdesc="Fast parser based on parsing expression grammars (PEGs) - Python 2 version."
  depends=('python>=2.7')

  cd "${srcdir}/${_name}-${pkgver}-python2"

  python2 setup.py install --skip-build --root="${pkgdir}" --optimize=1
  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}