blob: bd5b92f76857071cccca7010a18093f5b639ca07 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer : Daniel Bermond < gmail-com: danielbermond >
pkgbase=python-peachpy-git
pkgname=('python-peachpy-git' 'python2-peachpy-git')
_srcname=PeachPy
pkgver=r362.01d1515
pkgrel=3
pkgdesc='Python framework for writing high-performance assembly kernels (git version)'
arch=('any')
url='https://github.com/Maratyszcza/PeachPy/'
license=('BSD')
makedepends=(
# binary repositories:
'git' 'python' 'python-setuptools' 'python-sphinx'
'python2' 'python2-setuptools' 'python2-sphinx' 'python2-enum34'
# AUR:
'python-sphinx-bootstrap-theme' 'python2-sphinx-bootstrap-theme'
)
source=('git+https://github.com/Maratyszcza/PeachPy.git')
sha256sums=('SKIP')
prepare() {
cp -a "$_srcname" "${_srcname}-py2"
}
pkgver() {
cd "$_srcname"
# git, no tags available
printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
printf '%s\n' ' -> Building for Python...'
cd "$_srcname"
python setup.py build
python setup.py build_sphinx --all-files --source-dir="${srcdir}/${_srcname}/sphinx"
printf '%s\n' ' -> Building for Python2...'
cd "${srcdir}/${_srcname}-py2"
python2 setup.py build
python2 setup.py build_sphinx --all-files --source-dir="${srcdir}/${_srcname}-py2/sphinx"
}
package_python-peachpy-git() {
pkgdesc='Python3 framework for writing high-performance assembly kernels (git version)'
depends=('python' 'python-six')
cd "$_srcname"
python setup.py install --root="$pkgdir" --skip-build --optimize='1'
# doc
mkdir -p "${pkgdir}/usr/share/doc/${pkgname%-git}"
cp -a "${srcdir}/${_srcname}/build/sphinx/html/"* "${pkgdir}/usr/share/doc/${pkgname%-git}"
# license
install -D -m644 LICENSE.rst "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
package_python2-peachpy-git() {
pkgdesc='Python2 framework for writing high-performance assembly kernels (git version)'
depends=('python2' 'python2-six' 'python2-enum34')
cd "${_srcname}-py2"
python2 setup.py install --root="$pkgdir" --skip-build --optimize='1'
# doc
mkdir -p "${pkgdir}/usr/share/doc/${pkgname%-git}"
cp -a "${srcdir}/${_srcname}-py2/build/sphinx/html/"* "${pkgdir}/usr/share/doc/${pkgname%-git}"
# license
install -D -m644 LICENSE.rst "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|