blob: 98caec924d177e9e6f19793bc8e9f4083d8cbd9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Carl Smedstad <carsme@archlinux.org>
pkgname=python-picologging
_pkgname=${pkgname#python-}
pkgver=0.9.3
pkgrel=4
pkgdesc="An optimized logging library for Python"
arch=(x86_64)
url="https://github.com/microsoft/picologging"
license=(MIT)
depends=(
gcc-libs
glibc
python
)
makedepends=(
cmake
ninja
python-build
python-installer
python-scikit-build
python-setuptools
python-wheel
)
checkdepends=(
python-flaky
python-hypothesis
python-pytest
python-pytest-memray
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
sha256sums=('ed5e9d31c2d06fd02d4304bfb98cb200acbf11e1f03d6a5b341263cf312a18b2')
_archive="$_pkgname-$pkgver"
build() {
cd "$_archive"
export CMAKE_ARGS=-Wno-dev
python -m build --wheel --no-isolation --skip-dependency-check
}
check() {
cd "$_archive"
rm -rf tmp_install
python -m installer --destdir=tmp_install dist/*.whl
local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
export PYTHONPATH="$PWD/tmp_install/$site_packages"
# Deselected test fails with MEMORY PROBLEMS in a chroot.
pytest \
--deselect tests/unit/test_logger.py::test_nested_frame_stack
}
package() {
cd "$_archive"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|