blob: 0edb7c64c8e252c5571a4d3e61ba249139e1a308 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Grey Christoforo <first name at last name dot net>
# Co-Maintainer: Bert Peters <bert@bertptrs.nl>
pkgname=python-plotly
pkgver=5.20.0
pkgrel=2
pkgdesc="An open-source, interactive graphing library"
arch=('any')
url="https://github.com/plotly/plotly.py"
license=('MIT')
depends=(
python
python-tenacity
)
# optdepends based on optional_requirements.txt
optdepends=(
ipython
jupyterlab
python-ipywidgets
python-numpy
python-matplotlib
python-pillow
python-scipy
python-ipykernel
python-pandas
python-colorcet
python-inflect
python-psutil
)
makedepends=(
git
python-wheel
python-build
python-installer
python-setuptools
python-jupyter_core
python-tornado
jupyterlab
)
checkdepends=(
python-requests
python-pytest
)
source=(
"${pkgname}::git+https://github.com/plotly/plotly.py#tag=v$pkgver"
)
options=(!strip !debug) # strip and debug aren't useful for python files and take forever
sha256sums=('SKIP')
build() {
cd python-plotly/packages/python/plotly
# Skip the dependency check as the version bounds on jupyterlab are too tight
# and don't allow 4.x, which Arch currently ships.
SKIP_NPM=1 python -m build --wheel --no-isolation --skip-dependency-check
}
check() {
cd python-plotly/packages/python/plotly
pytest plotly/tests/test_core
}
package() {
cd python-plotly/packages/python/plotly
python -m installer --destdir="$pkgdir"/ dist/*.whl
mv "${pkgdir}/usr/etc" "${pkgdir}"
install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|