blob: 5a8079b52588f5e52e3fd3ec363d1ef22083d260 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=python-posthog
_name=posthog-python
pkgver=3.4.2
pkgrel=1
pkgdesc="Integrate PostHog into any python application."
arch=('any')
url="https://posthog.com/docs/libraries/python"
license=('MIT')
depends=(
'python-backoff'
'python-dateutil'
'python-monotonic'
'python-requests'
'python-six'
)
makedepends=(
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
checkdepends=(
'python-freezegun'
'python-mock'
'python-pytest'
'python-pytest-timeout'
)
source=("$_name-$pkgver.tar.gz::https://github.com/PostHog/posthog-python/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('8c5f7aad165f30ead15df28a045077856ed193097e2d7133f8ce37665e1aad6a')
build() {
cd "$_name-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "$_name-$pkgver"
# Disable tests requiring network access
pytest -k 'not test_request'
}
package() {
cd "$_name-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|