blob: 042605d5539b5f271f335150d67e8fefd3b237d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Maintainer: Erich Eckner <arch at eckner dot net>
pkgbase=python-postpic
pkgname=(python-postpic python2-postpic)
_pkgname="${pkgbase#*-}"
pkgver=0.4
pkgrel=3
pkgdesc='The open source particle-in-cell post processor.'
url='https://github.com/skuschel/postpic'
arch=('i686' 'pentium4' 'x86_64')
license=('GPL3')
_deppy2=(
'python2>=2.7'
'python2<2.8'
)
_deppy=(
'python>=3.8'
'python<3.9'
)
_depends=(
'python-matplotlib' 'python-numpy>=1.7' 'python-scipy' 'python-future' 'python-urllib3' 'python-numexpr'
)
_makedepends=(
'python-setuptools'
'cython'
'python-h5py'
)
_optdepends=(
'python-h5py: h5 reader for openPMD support'
'python-sdf: sdf support for EPOCH reader'
)
makedepends=(
"${_deppy[@]}"
"${_deppy2[@]}"
"${_depends[@]}"
"${_depends[@]/python/python2}"
"${_makedepends[@]}"
"${_makedepends[@]/ython/ython2}"
)
source=("$_pkgname-$pkgver.tar.gz::https://github.com/skuschel/${_pkgname}/archive/v$pkgver.tar.gz")
sha512sums=('c1a2ce68e7df5c4f16b01f46d2e171ac48c3eeddc7b2c219c6b070df5e4e4521b81ff9b7b45b514ff78b4866a1bfa44ad83ce357865c59d3b4f86e274d81fe69')
prepare() {
cp -a ${_pkgname}-${pkgver}{,-py2}
}
build() {
echo "Building python..."
(cd ${_pkgname}-${pkgver}
python setup.py build
)
echo "Building python2..."
(cd ${_pkgname}-${pkgver}-py2
python2 setup.py build
)
}
check() {
echo "Checking python..."
(cd ${_pkgname}-${pkgver}
python setup.py test
)
echo "Checking python2..."
(cd ${_pkgname}-${pkgver}-py2
python2 setup.py test
)
}
package_python-postpic() {
depends=(
"${_deppy[@]}"
"${_depends[@]}"
)
optdepends=("${_optdepends[@]}")
cd ${_pkgname}-${pkgver}
python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build
install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
#install -Dm 644 CHANGES README -t "${pkgdir}"/usr/share/doc/${pkgname}
}
package_python2-postpic() {
depends=(
"${_deppy2[@]}"
"${_depends[@]/python/python2}"
)
optdepends=("${_optdepends[@]/python/python2}")
cd ${_pkgname}-${pkgver}-py2
python2 setup.py install --prefix=/usr --root="${pkgdir}" --skip-build
install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
#install -Dm 644 CHANGES README -t "${pkgdir}"/usr/share/doc/${pkgname}
}
# vim: ts=2 sw=2 et:
|