PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

# Maintainer: Weirch Sodora <sodora at gmail dot com>

pkgbase=python-proboscis
pkgname=('python-proboscis' 'python2-proboscis')
pkgver=1.2.6.0
pkgrel=1
pkgdesc='Proboscis is a Python test framework that extends Python’s built-in unittest module and Nose with features from TestNG.'
arch=('any')
url='https://pypi.python.org/pypi/proboscis/'
license=('Apache')
makedepends=('python-setuptools' 'python2-setuptools')
source=("http://pypi.python.org/packages/source/p/proboscis/proboscis-${pkgver}.tar.gz")
md5sums=('e4b36449ef7c18f70b8243f4c8bddbca')

prepare() {
    cd "${srcdir}"
    cp -a proboscis-${pkgver} proboscis-${pkgver}-py2
}

package_python-proboscis() {
    depends=('python')
    cd "${srcdir}/proboscis-${pkgver}"
    python setup.py install --root="${pkgdir}" --optimize=1
}

package_python2-proboscis() {
    depends=('python2')
    cd "${srcdir}/proboscis-${pkgver}-py2"
    python2 setup.py install --root="${pkgdir}" --optimize=1
}