PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Patrick Northon <northon_patrick3@yahoo.ca>
# Contributor: jmcb <joelsgp@protonmail.com>
# Contributor: Jonas DOREL <jonas at dorel dot me>

pkgname=python-prospector
_name=prospector
pkgver=1.19.1
pkgrel=1
pkgdesc="Python static analysis tool"
url="https://github.com/PyCQA/prospector/"
depends=('python')
optdepends=('bandit: security linter'
            'mypy: optional type checking'
            'python-pyroma: check setup.py'
            'vulture: find dead code'
            'python-ruff: python linter'
            'pyright: python type checker')
makedepends=('python-poetry'
             'python-wheel')
license=('GPL-2.0-only')
arch=('any')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${_name}-dev/${_name}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('b1914900d80818192bacbf2c60044477d5eb8d5d4d2e525d2b9653bf91570146')

build() {
	cd "$_name-$pkgver"
	python -m build --wheel --no-isolation
}

package() {
	depends+=(
		'python-pylint'
		'python-pylint-celery'
		'python-pylint-django'
		'python-requirements-detector'
		'python-yaml'
		'python-mccabe'
		'python-pyflakes'
		'python-pycodestyle'
		'python-pep8-naming'
		'python-pydocstyle'
		'python-dodgy'
		'python-toml'
		'python-setoptconf'
		'python-packaging'
		'python-flake8')

	cd "$_name-$pkgver"
	python -m installer --destdir="$pkgdir" dist/*.whl
}