blob: 44281f8ab8b83ee5fdefeae00b8ee4a4fb30cc28 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Boris Momcilovic <boris.momcilovic@gmail.com>
# Contributor: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Elis Hughes <elishughes@googlemail.com>
# Contributor: Mark Blakeney at bullet-systems dot net
pkgname=python-pssh
pkgver=2.3.5
pkgrel=11
pkgdesc="Parallel versions of the openssh tools ssh, scp, rsync, nuke, slurp"
arch=('any')
url="https://github.com/lilydjwg/pssh"
license=('BSD')
depends=('openssh' 'python')
makedepends=('python-build' 'python-installer' 'python-wheel' 'patch')
changelog=$pkgname.changelog
source=(https://github.com/lilydjwg/pssh/archive/refs/tags/v${pkgver}.tar.gz
pssh-valueerror-the-fd-4-must-be-in-non-blocking-mode.patch)
sha256sums=('97277f9d08b512c6a1b6dc5eac9677f34038096bae24484452d326137ba0d080'
'40b01fd5c2aa59542a5d1bf65a41b861733f71305a9799c1d1ca6661f228a891')
prepare() {
cd "${srcdir}"/pssh-$pkgver
# fix FS#46571
patch -Np0 -i ../pssh-valueerror-the-fd-4-must-be-in-non-blocking-mode.patch
}
build() {
cd "${srcdir}"/pssh-$pkgver
python -m build --wheel --no-isolation
}
package() {
cd "${srcdir}"/pssh-$pkgver
python -m installer --destdir="$pkgdir" dist/*.whl
# fix putty pscp file conflict
mv "${pkgdir}"/usr/bin/pscp "${pkgdir}"/usr/bin/psshscp
# license
install -Dm644 COPYING "${pkgdir}"/usr/share/licenses/$pkgname/COPYING
}
|