summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ac3001b759f0c99ef83a3800c136b99ef45e3c95 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: TankMissile <alecfeldman@disroot.org>
# Contributor: ahrs <forward.to@hotmail.co.uk>

_pkgname="python-pulse-control-git"
_pkgname2="python2-pulse-control-git"
pkgname=($_pkgname $_pkgname2)
pkgver=r193.344b6b6
pkgrel=1
pkgdesc="Python high-level interface and ctypes-based bindings for PulseAudio (git version)."
url="http://github.com/mk-fg/${_pkgname%-git}"
license=("MIT")
arch=("any")
makedepends=("python-setuptools" "python2-setuptools")
source=("$_pkgname::git+$url.git")
md5sums=("SKIP")

pkgver() {
	cd $_pkgname
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cp -r $_pkgname $_pkgname2
}

build() {
	cd $_pkgname
	python setup.py build
	cd ../$_pkgname2
	python2 setup.py build
}

package_python-pulse-control-git() {
	depends=("python" "pulseaudio")
	provides=("python-pulse-control")
	conflicts=("python-pulse-control")
	cd $_pkgname
	python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
}

package_python2-pulse-control-git() {
	depends=("python2" "pulseaudio")
	provides=("python2-pulse-control")
	conflicts=("python2-pulse-control")
	cd $_pkgname2
	python2 setup.py install --root="$pkgdir/" --optimize=1 --skip-build
}