blob: 2f4cd65727e2b9be257b4ae56b641daa65789ffc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>
pkgname=python-py-serializable
_gitpkgname=serializable
pkgver=1.1.1
pkgrel=1
pkgdesc='Serialize and deserialize Python objects to and from JSON and XML'
arch=('any')
url='https://github.com/madpah/serializable'
license=('Apache-2.0')
depends=('python' 'python-defusedxml')
checkdepends=('python-lxml' 'xmldiff')
makedepends=('python-build' 'python-installer' 'python-poetry-core' 'python-wheel')
options=('!debug' '!strip')
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/madpah/serializable/archive/v${pkgver}.tar.gz"
)
sha512sums=('afaa990d4470e028e000d4789452fb7b214d5c26b89306e15e1f860556cbba4ef83036f07ac5d42b813553ed3a716182314bf854aa340bf70a232f9196a2beff')
build() {
cd "${srcdir}/${_gitpkgname}-${pkgver}"
python -m build --wheel --no-isolation
}
check() {
cd "${srcdir}/${_gitpkgname}-${pkgver}"
python -m unittest
}
package() {
cd "${srcdir}/${_gitpkgname}-${pkgver}"
python -I -m installer --destdir="${pkgdir}" dist/*.whl
install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
|