blob: 83842563897d41faf049ca8142cc6b8f215c8adc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Gilrain <gilrain+libre.arch A_T castelmo DOT_ re>
pkgbase=python-pyexecjs
pkgname=('python-pyexecjs' 'python2-pyexecjs')
pkgver=1.4.1
pkgrel=1
pkgdesc="Run JavaScript code from Python."
arch=('any')
url="https://pypi.python.org/pypi/PyExecJS"
license=('MIT')
makedepends=('python-setuptools' 'python2-setuptools')
optdepends=('v8: Google JavaScript engine'
'nodejs: built on Chrome V8 JavaScript engine'
'phantomjs: a headless WebKit'
'spidermonkey: Mozilla JavaScript engine')
changelog=changelog
source=(https://github.com/doloopwhile/PyExecJS/archive/$pkgver.tar.gz)
sha256sums=('04e68e4e4e03c1b2759afcd6273fcd977352ec20222edee1713d9410ed0d40b7')
prepare() {
cp -a PyExecJS-$pkgver{,-python2}
}
build() {
cd "PyExecJS-$pkgver"
python setup.py build
cd "../PyExecJS-$pkgver-python2"
python2 setup.py build
}
check() {
cd "PyExecJS-$pkgver"
LC_CTYPE=en_US.utf8 python test_execjs.py || warning "Tests failed"
cd "../PyExecJS-$pkgver-python2"
LC_CTYPE=en_US.utf8 python2 test_execjs.py || warning "Tests failed"
}
package_python-pyexecjs() {
depends=('python-six')
cd "PyExecJS-$pkgver"
python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1 --skip-build
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
package_python2-pyexecjs() {
depends=('python2-six')
cd "PyExecJS-$pkgver-python2"
python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1 --skip-build
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|