PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
_base=PyFVTool
pkgname=python-${_base,,}
pkgver=0.4.2
pkgrel=2
pkgdesc="Finite volume toolbox in Python"
arch=(any)
url="https://github.com/FiniteVolumeTransportPhenomena/${_base}"
license=(MIT)
depends=(python-scipy python-matplotlib)
makedepends=(python-build python-installer python-setuptools
  python-sphinx python-myst-parser python-nbsphinx python-sphinx_rtd_theme pandoc-cli)
checkdepends=(python-pytest python-tqdm python-pypardiso)
source=(${_base}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
sha512sums=('da3476288acb22e5bbed548f0a98fddb3e22e6f7ad264b902e3cea595bc2cf96e0e4df9641af6f09e7175c0447eea39bbf14820409bda03e8a9ff6fa75d15839')

build() {
  cd ${_base}-${pkgver}
  python -m build --wheel --skip-dependency-check --no-isolation
  cd docs
  sphinx-apidoc ../src/pyfvtool -o ./source/pyfvtool_api_autodoc
  make html
}

check() {
  cd ${_base}-${pkgver}
  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer dist/*.whl
  test-env/bin/python -m pytest tests
}

package() {
  cd ${_base}-${pkgver}
  PYTHONPYCACHEPREFIX="${PWD}/.cache/cpython/" python -m installer --destdir="${pkgdir}" dist/*.whl
  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -d "${pkgdir}/usr/share/doc/${pkgname}"
  mv docs/build/html "${pkgdir}/usr/share/doc/${pkgname}"
}