PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Contributor: PRESFIL <echo cHJlc2ZpbEBwcm90b25tYWlsLmNvbQo= | base64 -d>
# Contributor: Falk Alexander Seidl <fa@terminal.run>

pkgname=python-pykeepass-git
_gitname=pykeepass
pkgver=v4.1.1.post1.r1.g2b051d9 # renovate: datasource=github-tags depName=libkeepass/pykeepass
pkgrel=1
pkgdesc="Python library to interact with keepass databases"
arch=("any")
license=("GPL3")
url="https://github.com/libkeepass/pykeepass"
depends=("python-argon2_cffi" "python-construct" "python-lxml" "python-pycryptodomex" "python-setuptools")
makedepends=("git" "python-build" "python-installer" "python-wheel")
checkdepends=("python-pyotp")
provides=(python-pykeepass)
conflicts=(python-pykeepass)
source=("git+https://github.com/libkeepass/pykeepass.git")
sha512sums=('SKIP')

pkgver() {
    cd "${srcdir}/${_gitname}/"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^pykeepass\.//'
}

build() {
    cd "${srcdir}/${_gitname}/"
    python -m build --wheel --no-isolation
}

check() {
    cd "${srcdir}/${_gitname}/"
    python -m unittest tests.tests
}

package() {
    cd "${srcdir}/${_gitname}/"
    python3 -m installer --destdir="${pkgdir}" dist/*.whl
}