blob: dc126ae454ac12244ed8aaa0d69c22daa262a50a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: 0x9fff00 <0x9fff00+git@protonmail.ch>
_name=PyMCTranslate
pkgname=python-${_name,,}
pkgver=1.2.22
_commit=c50c2671d0fa63e0c3fedaac39e36f30ceaa51a2
pkgrel=2
pkgdesc='A library of block mappings that can be used to convert from any Minecraft format into any other Minecraft format'
arch=('any')
url="https://github.com/gentlegiantJGC/$_name"
license=('LicenseRef-Amulet-Team-1.0.0')
depends=('python' 'python-amulet-nbt' 'python-numpy')
makedepends=('git' 'python-build' 'python-installer' 'python-setuptools' 'python-versioneer' 'python-wheel')
# tests directory isn't in pypi sdist
# github tarball has unstable hash due to https://github.com/gentlegiantJGC/PyMCTranslate/blob/45024a6ca12592913e6249269d8a180b2940f6aa/PyMCTranslate/_version.py#L25
source=("git+$url.git#commit=$_commit")
sha256sums=('SKIP')
prepare() {
cd "$_name"
# expand placeholders
git archive --format tar HEAD PyMCTranslate/_version.py | tar -x
# use current versioneer
sed -Ei 's/(versioneer)-518/\1/' pyproject.toml
}
build() {
cd "$_name"
python -m build --wheel --no-isolation
}
check() {
cd "$_name"
python -m unittest discover -s tests
}
package() {
cd "$_name"
python -m installer --destdir="$pkgdir" dist/*.whl
# https://wiki.archlinux.org/title/Python_package_guidelines#Using_site-packages
local _site_packages="$(python -c 'import site; print(site.getsitepackages()[0])')"
install -d "$pkgdir/usr/share/licenses/$pkgname"
local _license_path="$_site_packages/$_name-$pkgver.dist-info/LICENSE"
[ -f "$pkgdir/$_license_path" ] || { echo "License file not found"; exit 1; }
ln -s "$_license_path" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|