blob: 5b6621284c5aec7261634e979db0e1f396dc3686 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
_pkgname=pymssql
pkgname=python-pymssql
pkgver=2.3.6
pkgrel=1
pkgdesc='DB-API (PEP-249) interface to Microsoft SQL Server'
arch=('x86_64')
url='https://github.com/pymssql/pymssql'
license=('LGPL-2.1-or-later')
depends=(
freetds
glibc
)
makedepends=(
cython
python-build
python-installer
python-setuptools
python-setuptools-scm
python-tomli
python-wheel
)
checkdepends=(
python-gevent
python-psutil
python-pytest
python-pytest-timeout
python-sqlalchemy
)
source=("${_pkgname}-${pkgver}.tar.gz::https://files.pythonhosted.org/packages/source/${_pkgname::1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
sha512sums=('3abdf2db32a18b6a9193f76327cf2da881aa16d3642dfd44e9b2413ec80b281ff4be072e018c7ded18d1fab2d8b00b3d2c77b3af328962b2d55bd82321c330bf')
build() {
cd "${_pkgname}-${pkgver}"
python -m build --wheel --no-isolation -x
}
check() {
local python_version=$(python -c 'import sys; print("".join(map(str, sys.version_info[:2])))')
cd "${_pkgname}-${pkgver}"
PYTHONPATH="${PWD}/build/lib.linux-${CARCH}-cpython-${python_version}" pytest -v
}
package() {
cd "${_pkgname}-${pkgver}"
python -m installer --destdir="${pkgdir}" dist/*.whl
}
# vim:set ts=2 sw=2 et:
|