blob: 14681b59d30762b59f3b8a606c0cdf77382871ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
_pkgname=pymssql
pkgname=python-pymssql
pkgver=2.2.9
pkgrel=1
pkgdesc='A simple database interface for Python that builds on top of FreeTDS to provide a Python DB-API (PEP-249) interface to Microsoft SQL Server'
arch=('x86_64')
url='https://github.com/pymssql/pymssql'
license=('LGPL2.1')
depends=(
freetds
)
makedepends=(
cython
python-pip
python-setuptools
)
checkdepends=(
python-gevent
python-psutil
python-pytest
python-pytest-timeout
python-sqlalchemy
)
source=("${_pkgname}-${pkgver}.tar.gz::https://files.pythonhosted.org/packages/source/${_pkgname::1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
sha512sums=('d3626a12b59e4e8132a7f94b84650d729a454661775e7a65a8ae458b2f875d5e98f09e5b9252bbd8b4dbebb6496474ce2840371f7cb8859333a5b1b27982097f')
build() {
cd "${_pkgname}-${pkgver}"
python setup.py build
}
check() {
local python_version=$(python -c 'import sys; print("".join(map(str, sys.version_info[:2])))')
cd "${_pkgname}-${pkgver}"
PYTHONPATH="${PWD}/build/lib.linux-${CARCH}-cpython-${python_version}" pytest -v
}
package() {
cd "${_pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}
# vim:set ts=2 sw=2 et:
|