blob: 47b53e6b6b8a7a8b32edb0c5be204b45a8a13517 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Chris Tam <LChris314 at gmail dot com>
pkgname=python-pyperclip-git
pkgver=r197.d72f3ce
pkgrel=2
pkgdesc="A cross-platform clipboard module for Python (git)"
arch=('any')
url="https://github.com/asweigart/pyperclip"
license=('BSD')
makedepends=('python-setuptools')
# GTK/Qt tests crash xvfb, and Klipper tests require a running klipper
checkdepends=('xorg-server-xvfb' 'python-pytest' 'xsel' 'xclip')
depends=('python')
optdepends=('xclip: xclip backend'
'xsel: xsel backend'
'plasma-workspace: klipper backend')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("pyperclip::git+${url}.git")
sha512sums=('SKIP')
pkgver() {
cd pyperclip
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd pyperclip
python setup.py build
}
check() {
cd pyperclip
PYTHONPATH="${PWD}/build/lib:${PYTHONPATH}" xvfb-run py.test
}
package() {
cd pyperclip
python setup.py install --root="$pkgdir" --optimize=1
install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname%-git}/LICENSE.txt"
}
# vim:set ts=2 sw=2 et:
|