blob: 257227d6a23f25c4fe983d68810936f2d1170164 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Dråfølin <derg@drafolin.ch>
pkgname=python-pypresence-git
_stablename=${pkgname%-git}
_name=${_stablename#python-}
pkgver=4.3.0.r41.g4e882c3
pkgrel=1
pkgdesc='Discord RPC and Rich Presence wrapper library - git version'
url='https://github.com/qwertyquerty/pypresence'
arch=(any)
license=(MIT)
depends=(python)
makedepends=(
python-build
python-installer
python-setuptools
python-sphinx
python-wheel
git
)
conflicts=('python-pypresence')
provides=("python-pypresence=$pkgver")
source=("$_name::git+$url.git")
b2sums=('SKIP')
pkgver() {
cd $_name
( set -o pipefail
git describe --tags --long --abbrev=7 2>/dev/null | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
)
}
build() {
cd $_name
python -m build --wheel --no-isolation
sphinx-build -b man docs/sphinx man
}
package() {
cd $_name
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 -t "$pkgdir"/usr/share/man/man1 man/pypresence.1
install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE
}
|