blob: 1f608522f04459c8f7d1acde45e144b29954b5cd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Morgenstern <charles [at] charlesbwise [dot] com>
pkgname=python-pyqt-qwt
_pkgname=PyQt-Qwt
_commit=d98d49904765c03c11c400b9d7fc4e52a2418cdd
pkgver=1.02.02.20210915
pkgrel=4
pkgdesc="Python PyQt wrapper for Qwt 6"
arch=('x86_64')
url="https://github.com/GauiStori/${_pkgname}"
license=('LGPL-2.1-only WITH Qwt-exception-1.0')
depends=('python'
'python-pyqt5'
'qwt>=6.1.4')
optdepends=('python-numpy: required for some of the provided Qt 5 examples')
makedepends=('pyqt-builder'
'sip>=4.18')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/piannucci/${_pkgname}/archive/${_commit}.tar.gz")
sha512sums=('042e75397f43d82d41ce20274086d270fc3f5952be9742b1f77e85fab33fff28e241d870ed6cfb84671b1350eb6765a451979cef0d3f8c31e4b1e5c9d55fa17c')
prepare() {
mv "${_pkgname}-${_commit}" "${pkgname}-${pkgver}"
}
build() {
cd "${pkgname}-${pkgver}"
sip-build --verbose \
--qwt-incdir=/usr/include/qwt \
--qwt-libdir=/usr/lib \
--qwt-lib=qwt
}
package() {
cd "${pkgname}-${pkgver}/build"
make INSTALL_ROOT="$pkgdir" install
install -Dm0644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|