blob: 158c1a0aa211c7f1f4b422d2a5cd4f50b3cf382b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
pkgbase=python-pyrsistent
pkgname=('python-pyrsistent' 'python2-pyrsistent')
pkgver=0.12.3
pkgrel=1
pkgdesc="Persistent/Functional/Immutable data structures"
arch=('i686' 'x86_64')
license=('MIT')
url="https://github.com/tobgu/pyrsistent"
makedepends=('python-setuptools' 'python2-setuptools')
checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-hypothesis' 'python2-hypothesis')
source=("https://pypi.io/packages/source/p/pyrsistent/pyrsistent-$pkgver.tar.gz"
LICENCE.mit)
sha512sums=('f66449865c54ff05e85b6f51927d346b4699b6c41eeb0da6e81e92efa4b03c45c25296390914638fca44369420e0c57754e794995dac832453537c1ad29dfaa8'
'036bd5cc2a62b004576ecc50a84dc7d187d8108f52cb886f7e32bed324327af2dc132100e1c8f1dd2ce35b774f74898020f04a315e5137319deda18a449e791a')
prepare() {
cp -a pyrsistent-$pkgver{,-py2}
}
build() {
cd "$srcdir"/pyrsistent-$pkgver
python setup.py build
cd "$srcdir"/pyrsistent-$pkgver-py2
python2 setup.py build
}
check() {
cd "$srcdir"/pyrsistent-$pkgver
python setup.py pytest
cd "$srcdir"/pyrsistent-$pkgver-py2
python2 setup.py pytest
}
package_python-pyrsistent() {
depends=('python-six')
cd pyrsistent-$pkgver
python setup.py install --root="$pkgdir" --optimize=1
install -D -m644 ../LICENCE.mit "$pkgdir"/usr/share/licenses/$pkgname/LICENCE.mit
}
package_python2-pyrsistent() {
depends=('python2-six')
cd pyrsistent-$pkgver-py2
python2 setup.py install --root="$pkgdir" --optimize=1
install -D -m644 ../LICENCE.mit "$pkgdir"/usr/share/licenses/$pkgname/LICENCE.mit
}
|